You are viewing the documentation for Blueriq 17. Documentation for other versions is available in our documentation directory.
CONCATENATE
Use the '+
' (plus) operator to concatenate strings or a combination of strings and other type values to produce a single string value.
Syntax
string1 + string2 + ... + value1 + ...
- string1 - The first string that you want to concatenate.
- string2 - The second string that you want to concatenate.
- value1 - A value of some type of number, date or boolean that you want to add to the new string value.
Return type
- string
Examples
12 + " kilometers" = "12 kilometers"
"This statement is " + TRUE + "." = "This statement is true."
"I was born on " + Me.birthDateAndTime + "." (Me.birthDateAndTime = 01-12-1970 23:00:45) = "I was born on Tue Dec 01 23:00:45 CET 1970."
There exists a STR_CONCAT ( string , string )
function in the expression language. As it can only concatenate two strings, and is much longer in typing, we advise to use above way for concatenating strings.
JOIN
This function joins a series of values into one string, separated with a character of your choice.
Syntax
JOIN ( argument1 , argument2 , ... , separator )
- argument1, argument2 - Attributes or expressions that contain the values that will be joint to a single string. JOIN works for all base types, even multivalued.
- separator - A string value that will be used as separator symbol.
Return type
- string
The CONCAT
function is identical to the JOIN
function.
Examples
Suppose you have a model containing the following attributes.
Attribute | Basetype | Value |
---|---|---|
Person.name | string | "John" |
Person.date_of_birth | date | 01-01-1995 |
Person.family_name | string |
JOIN ( Person.name , Person.date_of_birth , ";" ) = "John;Sun Jan 01 00:00:00 CET 1995"
JOIN ( Person.name , Person.name , "@" ) = "John@John"
JOIN ( Person.name , Person.family_name , YEARS BETWEEN Person.date_of_birth AND DATE ( 2015 , 01 , 01 ) , ";" ) = "John;;20"
MATCH
The MATCH
function compares a string pattern to another string and returns TRUE if the string exactly matches the pattern, and otherwise FALSE. The MATCH function is case-sensitive.
Syntax
MATCH ( pattern , string )
- pattern - An attribute of base type string or a string value. String must be a valid regular expression. The regular expressions used in several Blueriq Studio functions are common Java 1.4 expressions. For a complete documentation we refer to the online java documentation.
- string - String value, attribute of base type string or an expression that results in a string value.
Return type
- boolean
Examples
If the attribute File.name
is of base type string and its value is "Thisfile_1.doc" then
MATCH ( "Thisfile_1.doc" , File.name ) = TRUE
MATCH ( File.name , "Thisfile_1.doc" ) = TRUE
MATCH ( " Thisfile_1.doc" , File.name ) = FALSE
MATCH ( "thisfile_1.doc" , File.name ) = FALSE
MATCH ( "[A-Z]hisfile_1.doc" , File.name ) = TRUE
MATCH ( "[a-z]hisfile_1.doc" , File.name ) = FALSE
MATCH ( "Thisfile_[0-9].doc" , File.name ) = TRUE
MATCH ( ".............." , File.name ) = TRUE
MATCH ( ".*" , File.name ) = TRUE
MATCH ( "**" , "**" ) results in an error message, because "**" is not a valid regular expression
FIND
The FIND
function looks for a string pattern within another string and returns the first matching characters. The function is case-sensitive.
Syntax
FIND ( pattern , string ) FIND ( pattern , string , startIndex )
- pattern - An attribute of base type string or a string value. String must be a valid regular expression. The regular expressions used in several Blueriq Studio functions are common Java 1.4 expressions. For a complete documentation we refer to the online java documentation.
- string - An attribute of base type string or an expression that results in a string.
- startIndex - A positive integer value indicating at which character of the string the search should start (inclusive). This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. The first character starts at index 0.
Return type
- string
Examples
If File.name
is an attribute of base type string with value "Thisfile_1.doc", then:
FIND ( "_[1-5]" , File.name ) = "_1"
FIND ( "File" , File.name ) = UNKNOWN
FIND ( "el" , "Hello" ) = "el"
FIND ( "el" , "Hello" , 2 ) = UNKNOWN
FIND ( "eo" , "Hello" ) = UNKNOWN
FIND ( "\s[a-zA-Z]+" , "Hello world example" ) = "world"
FIND ( "\s[a-zA-Z]+" , "Hello world example" , 6 ) = "example"
FIRST
FIRST returns the first character(s) of a string, based on the number of characters you specify.
Syntax
FIRST integer CHARACTERS OF string FIRST CHARACTER OF string
- integer - A positive integer value. This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. FIRST CHARACTER OF can be used to retrieve only the first character of the string.
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
If you prefer a functional syntax, you can use the STR_FRONT( string, integer ) function. Example: STR_FRONT("Blueriq", 3) = "Blu"
Examples
If File.name
is an attribute of base type string with value "Thisfile_1.doc" and the integer attribute File.prefix
has value 8 then:
FIRST File.prefix CHARACTERS OF File.name = "Thisfile"
FIRST CHARACTER OF File.name = "T"
FIRST 5 CHARACTERS OF "pieceofcake" = "piece"
LAST
LAST returns the last character(s) of a string, based on the number of characters you specify.
Syntax
LAST integer CHARACTERS OF string LAST CHARACTER OF string
- integer - A positive integer value. This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. LAST CHARACTER OF can be used to retrieve only the last character of the string.
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
If you prefer a functional syntax, you can use the STR_BACK ( string, integer ) function. Example: STR_BACK("Blueriq", 3) = "riq"
Examples
If File.name
is an attribute of base type string with value "Thisfile_1.doc" and the integer attribute File.extension
has value 3 then:
LAST File.extension CHARACTERS OF File.name = "doc"
LAST CHARACTER OF File.name = "c"
LAST 4 CHARACTERS OF "pieceofcake" = "cake"
LENGTH
LENGTH
returns the length of a string
Syntax
LENGTH ( string )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- integer
Spaces at the start of the end of the string are counted as well, the string is not trimmed.
Example
LENGTH ( "Blueriq" ) = 7
LENGTH ( " Blueriq " ) = 9
LENGTH ( ? ) = ?
UPPERCASE
UPPERCASE
returns a string with all characters in uppercase
Syntax
UPPERCASE ( string )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
Example
UPPERCASE ( "hello" ) = "HELLO"
UPPERCASE ( "WORLD" ) = "WORLD"
UPPERCASE ( "hello world " ) = "HELLO WORLD "
UPPERCASE ( " hELLo " ) = " HELLO "
UPPERCASE ( ? ) = ?
LOWERCASE
LOWERCASE
returns a string with all characters in lowercase
Syntax
LOWERCASE ( string )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
Example
LOWERCASE ( "hello" ) = "hello"
LOWERCASE ( "WORLD" ) = "world"
LOWERCASE ( "Hello World " ) = "hello world "
LOWERCASE ( " hELLo " ) = " hello "
LOWERCASE ( ? ) = ?
CAPITALIZE
CAPITALIZE
returns a string with the first character uppercased
Syntax
CAPITALIZE ( string ) CAPITALIZE ( string, lowerTheRest )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- lowerTheRest - An attribute of base type boolean, an expression that results in a boolean or a constant boolean value, indicating that the other characters need to be lowercased. This parameter is optional and if it is not supplied, the other characters are left untouched.
Return type
- string
Example
CAPITALIZE ( "hello" ) = "Hello"
CAPITALIZE ( "WORLD" ) = "WORLD"
CAPITALIZE ( "hello world " ) = "Hello world "
CAPITALIZE ( " hELLo " ) = " hELLo "
The input string is not trimmed, so in this case the first character is a space.
CAPITALIZE ( "hello" , TRUE ) = "Hello"
CAPITALIZE ( "WORLD" , TRUE ) = "World"
CAPITALIZE ( "hello world " , TRUE ) = "Hello world "
CAPITALIZE ( " hELLo " , TRUE ) = " hello "
The input string is not trimmed, so in this case the first character is a space.
CAPITALIZE( ? ) = ?
TRIM
TRIM
strips the leading and trailing spaces from a string
Syntax
TRIM ( string )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
Example
TRIM ( "Hello" ) = "Hello"
TRIM ( "Hello World" ) = "Hello World"
TRIM ( " Hello World " ) = "Hello World"
TRIM ( ? ) = ?
INDEXOF
INDEXOF
returns the index of the first occurrence of a specified substring in a string
Syntax
INDEXOF ( string , substring ) INDEXOF ( string , substring , startIndex )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- substring - An attribute of base type string, an expression that results in a string or a constant string value.
- startIndex - A positive integer value indicating at which character the search for the substring should start (inclusive). This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. The first character starts at index 0.
Return type
- integer - the index of the first occurrence of the specified substring or -1 if it is not found
Example
INDEXOF ( "Hello world" , "o" ) = 4
INDEXOF ( "Hello world" , "o" , 5 ) = 7
INDEXOF ( "Hello world" , "a" ) = -1
INDEXOF ( "Hello world" , "o" , 8 ) = -1
LASTINDEXOF
LASTINDEXOF
returns the index of the last occurrence of a specified substring in a string
Syntax
LASTINDEXOF ( string , substring ) LASTINDEXOF ( string , substring , startIndex )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- substring - An attribute of base type string, an expression that results in a string or a constant string value.
- startIndex - A positive integer value indicating at which character the search for the substring should start (inclusive), searching backwards. This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value.
Return type
- integer - the index of the last occurrence of the specified substring or -1 if it is not found
Example
LASTINDEXOF ( "Hello world" , "o" ) = 7
LASTINDEXOF ( "Hello world" , "o" , 6 ) = 4
LASTINDEXOF ( "Hello world" , "a" ) = -1
LASTINDEXOF ( "Hello world" , "o" , 3 ) = -1
SUBSTRING
SUBSTRING
returns the substring of a given string starting from the index provided and ending at the end index if provided, or the end of the string
Syntax
SUBSTRING ( string , startIndex ) SUBSTRING ( string , startIndex , endIndex )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- startIndex - A positive integer value indicating at which character the substring should start (inclusive). This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. The first character starts at index 0.
- endIndex - A positive integer value indicating at which character the substring should end (exclusive). This can be either an attribute of base type integer, an expression that results in an integer or a constant integer value. The
endIndex
cannot exceed the length of the string and should be larger than the startIndex.
Return type
- string
Example
SUBSTRING ( "Hello world" , 1 ) = "ello world"
SUBSTRING ( "Hello world" , 0 , 1 ) = "H"
SUBSTRING ( "Hello world" , 1 , 5 ) = "ello"
SUBSTRING ( "Hello world" , 0 ) = "Hello world"
SUBSTRING ( "Hello world" , 0 , LENGTH( "Hello world" ) ) = "Hello world"
SUBSTRING_BEFORE
SUBSTRING_BEFORE
returns the start of a given string before the first occurrence of substring, or an empty string if substring is not found
Syntax
SUBSTRING_BEFORE ( string , substring )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- substring - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
Example
SUBSTRING_BEFORE ( "hello:world" , ":" ) = "hello"
SUBSTRING_BEFORE ( "hello:world:all
" , ":" ) = "hello"
SUBSTRING_BEFORE ( "hello:world" , "h" ) = ""
SUBSTRING_BEFORE ( "hello:world" , "a" ) = ""
SUBSTRING_BEFORE ( "" , "hello" ) = ""
SUBSTRING_BEFORE ( "hello" , "" ) = ""
SUBSTRING_AFTER
SUBSTRING_AFTER
returns the end of a given string after the first occurrence of substring, or an empty string if substring is not found
Syntax
SUBSTRING_AFTER ( string , substring )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- substring - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- string
Example
SUBSTRING_AFTER ( "hello:world" , ":" ) = "world"
SUBSTRING_AFTER ( "hello:world:all
" , ":" ) = "world:all"
SUBSTRING_AFTER ( "hello:world" , "a" ) = ""
SUBSTRING_AFTER ( "" , "hello" ) = ""
SUBSTRING_AFTER ( "hello" , "" ) = ""
SPLIT
SPLIT
returns a multivalue attribute containing every substring that is delimited by the given pattern
Syntax
SPLIT ( string , pattern )
- string - An attribute of base type string, an expression that results in a string or a constant string value.
- pattern - An attribute of base type string or a string value. String must be a valid regular expression. The regular expressions used in several Blueriq Studio functions are common Java 1.4 expressions. For a complete documentation we refer to the online java documentation.
Return type
- string (multivalue)
Example
SPLIT ( "Hello world" , "o" ) = [ "Hell" , " w" , "rld" ]
SPLIT ( "Hello world" , "a" ) = [ "Hello world" ]
SPLIT ( "Hello" , "o" ) = [ "Hell" ]
SPLIT ( "ooo" , "o" ) = [ ]
- Usage: remove dots from a string in combination with the JOIN function
JOIN ( SPLIT ( "H.E.L.L.O" , "\.") , "" ) = "HELLO"
REPLACE
The REPLACE
function replaces every occurrence of a string pattern within another string with a provided replacement string The function is case-sensitive.
Syntax
REPLACE ( pattern , string , replacement )
- pattern - An attribute of base type string or a string value. String must be a valid regular expression. The regular expressions used in several Blueriq Studio functions are common Java 1.4 expressions. For a complete documentation we refer to the online java documentation.
- string - An attribute of base type string or an expression that results in a string.
- replacement - An attribute of base type string or an expression that results in a string.
Return type
- string. If the pattern is not found, the original string is returned.
Examples
REPLACE ( ":", "hello:world:example" , " " ) = "hello world example"
REPLACE ( "o" , "hello world" , "a" ) = "hella warld"
REPLACE ( "O" , "hello world" , "a" ) = "hello world"
REPLACE ( "\s" , "hello world example" , "" ) = "helloworldexample"
REPLACE ( "\d{2}" , "hello1 world22 example333" , "@" ) = "hello1 world@ example@3"
REPLACE ( "" , "hello world" , " " ) = " h e l l o w o r l d "
EQUALS
EQUALS
compares two strings and returns TRUE if and only if they are equal. This function is case sensitive.
Only use this function if you need a case sensitive comparison of two strings. If you want to compare strings case insensitive, use the '=' operator instead.
Syntax
EQUALS ( string1 , string2 ) string1 EQUALS string2
- string1 - An attribute of base type string, an expression that results in a string or a constant string value.
- string2 - An attribute of base type string, an expression that results in a string or a constant string value.
Return type
- boolean
Example
EQUALS ( "hello" , "hello" ) = TRUE
EQUALS ( "hello" , "Hello" ) = FALSE
Note that "hello" = "Hello" will return TRUE because it is case insensitive
EQUALS ( "hello" , "hello " ) = FALSE
EQUALS ( "" , "" ) = TRUE