Text Substitution Language: TSL

TSL comment

You can use TSL comment tags in order to add comment to your TSL.

Syntax

/* [text] */

Inputs: 

• text: to be commented out

Example

/* The statement below creates a list of all user names. 
This is a multi line comment. */
[[[FOREACH user]]]Name: [[[user.last_name]]], [[[user.first_name]]][[[/FOREACH]]]

Back to Top

TSL IF statement

The IF statement enables you to selectively perform tasks within your TSL message, based on some criteria which evaluate to TRUE or FALSE.

Syntax

[[[IF expr]]] message [[[/IF]]]

Inputs

• expr: is an expression that evaluates to TRUE or FALSE

• message: is a TSL message, so it can contain plain text and other TSL conditions

Example

Suppose you want to create a welcoming message after a user has logged in to your application. Then you could create the following TSL message:

Welcome [[[IF user.gender = 'male']]]Mr.[[[/IF]]] [[[IF user.gender = 'female']]]Mrs.[[[/IF]]] [[[user.first_name]]] [[[user.last_name]]]

When user John Doe logged on, the message shown in your application is: “Welcome Mr. John Doe”

When user Jane Doe logged on, the message shown in your application is: “Welcome Mrs. Jane Doe”

If the gender is unknown the message will look like this: “Welcome Jane Doe”

Back to Top

TSL IF ELSEIF statement

The IF ELSEIF statement enables you to selectively perform tasks within your TSL message, based on some criteria, which evaluate to TRUE or FALSE.

When TRUE executes the task specified in the IF part of the statement, the task specified in the ELSEIF part of the statement is only executed when the specified criteria are met.

Syntax

[[[IF expr1]]] message1 [[[ELSEIF expr2]]] message2 [[[/IF]]]

Inputs

• expr1 and expr2: are expressions which evaluate to TRUE or FALSE

• message1 and message2: are TSL messages, so they can contain plain text and other TSL conditions.

Example

Suppose you want to create a welcoming message after a user has logged in to your application. Then you could create the following TSL message:

[[[IF time.hour >= 0 AND time.hour < 6]]]Good night [[[ELSEIF time.hour >= 6 AND time.hour < 12]]]Good morning [[[ELSEIF time.hour >= 12 AND time.hour < 18]]]Good afternoon [[[ELSEIF time.hour >= 18 AND time.hour ⇐ 23]]]Good evening[[[/IF]]] [[[user.first_name]]] [[[user.last_name]]]

When user John Doe logged on at 8 o’clock am, the message shown in your application is: “Good morning John Doe”

When user John Doe logged on at 7 o’clock pm, the message shown in your application is: “Good evening John Doe”

Back to Top

TSL FOREACH IN statement

Use this statement to repeat a text for a subset of instances of an entity.

Syntax

[[[FOREACH entity IN relation]]] message [[[/FOREACH]]]

Inputs

• entity: is the child entity

• relation: is the relationship between the parent and the child entity

• message: is a TSL message, so it can contain plain text and other TSL conditions

Example

Suppose you created a parent and a child entity. The parent has a multivalue relation with the child via the attribute Parent.Has_Children.

If the following instances where created:

To create an overview of the children per parent you could create the following TSL message:

[[[FOREACH Parent]]] [[[Parent.Name]]] has children: [[[FOREACH Child IN Parent.Has_children]]] Name: [[[Child.Name]]] Date of birth: [[[Child.Date_of_birth]]], [[[/FOREACH]]] [[[/FOREACH]]]

This results in:

John has children: Name: Kim Date of birth: 26-09-1998, Name: Rick Date of birth: 13-05-2000, Name: Bob Date of birth: 03-08-2003 Dave has children: Name: Mary Date of birth: 04-06-1982

Back to Top

TSL FOREACH WHERE statement

Use this statement to repeat a text for a subset of instances of an entity.

Syntax

[[[FOREACH entity WHERE condition]]] message [[[/FOREACH]]]

Inputs

• entity: is the child entity

• condition: the condition that must hold for an instance

• message: is a TSL message, so it can contain plain text and other TSL conditions

Example

Suppose you have multiple persons. If the following instances where created:

To create an overview of all persons older than 40 you could create the following TSL message:

Persons older than 40: [[[FOREACH Person WHERE Person.Age>40]]] [[[Person.Name]]], [[[Person.Age]]]; [[[/FOREACH]]]

This results in:

Persons older than 40: Angela, 47; Dave, 82;

Back to Top

TSL FOREACH ORDER BY statement

When you use the FOREACH or FOREACH IN statement to repeat a text for multiple instances, you can add the ORDER BY statement to create an ordered list of texts. Add either DESC if you want to sort the list descending or ASC if you want to order the list ascending.

Syntax

[[[FOREACH entity ORDER BY attr DESC|ASC]]] message [[[/FOREACH]]]
[[[FOREACH entity IN relation ORDER BY attr DESC|ASC]]] message [[[/FOREACH]]]

Inputs

• entity: is the child entity

• attr: the attribute by which the list of instances will be ordered. DESC stands for descending order. ASC stands for ascending sort order

• message: is a TSL message, so it can contain plain text and other TSL conditions
• relation: is the relationship between the parent and the child entity

Back to Top